Formen Verformen

Wolfgang Kluge
wolfgang@vbwelt.de

Irgendwie ist Windows schon ganz schön langweilig...
Alles rechteckig. Dabei gibts so viele runde Fenster an Häusern...und spätestens seit WinAmp weiß jeder, daß auch unter Windows nicht alles so sein muß.
Hierbei sind der künstlerischen Ader keine Grenzen gesetzt. Man kann Runde/Elliptische Fenster erzeugen,...den Fenstern Runde Ecken verpassen und per Polygone auch beliebige Formen erzeugen...

Gemacht wird das mit Regionen. Regionen sind GDI-Objekte, die einen Bereich in einem Gerätekontext(Device Context) beschreiben.
Und Windows zeichnet nur innerhalb solcher Regionen...

Nun ist es ein leichtes, eine Region zu definieren, und dessen Handle dann einem Gerätekontext zuzuweisen...
Das einzigste, daß dabei zu beachten ist, sind die Koordinaten. Die sind nicht wie sonst Client-bezogen, sondern Fenster-bezogen, was bedeutet, daß die Überschrift(Caption) und die Ränder mit eingeschlossen sind...
Ausserdem (wie immer bei API-Funktionen) werden die Koordinaten in Pixel angegeben...

 Deklaration:
Private Type POINTAPI
  x As Long
  y As Long
End Type
Private Declare Function CreateRectRgn Lib "gdi32" (ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Private Declare Function CreateRoundRectRgn Lib "gdi32" (ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long, ByVal X3 As Long, ByVal Y3 As Long) As Long
Private Declare Function CreatePolygonRgn Lib "gdi32" (lpPoint As POINTAPI, ByVal nCount As Long, ByVal nPolyFillMode As Long) As Long
Private Declare Function CreateEllipticRgn Lib "gdi32" (ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long

Private Declare Function CombineRgn Lib "gdi32" (ByVal hDestRgn As Long, ByVal hSrcRgn1 As Long, ByVal hSrcRgn2 As Long, ByVal nCombineMode As Long) As Long

Private Declare Function SetWindowRgn Lib "user32" (ByVal hwnd As Long, ByVal hRgn As Long, ByVal bRedraw As Boolean) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long

' Für CombineRgn
Private Const RGN_AND = 1
Private Const RGN_OR = 2
Private Const RGN_XOR = 3
Private Const RGN_DIFF = 4
Private Const RGN_COPY = 5


Diese Funktionen sind nun relativ leicht anzuwenden. Wie man mehrere Regionen Kombinieren kann, wird weiter unten erklärt.

 Allen Gemeinsam:
Dim rgn As Long
' Rechteckige Region
rgn = CreateRectRgn(0, 0, 400, 400)

' Rechteckige Region mit Runden Ecken
rgn = CreateRoundRectRgn(5, 5, 400, 400, 10, 10)

' Runde/Elliptische Region
' Wenn X1 = Y1 und X2 = Y2 dann Kreisrund
rgn = CreateEllipticRgn(10, 10, 400, 300)

' Polygon - Region
' Der Erste Wert zeigt auf den ersten beschriebenen Punkt
' Der Zweite Wert(hier 8) beschreibt die Anzahl der Punkte
' Das Polygon muß nicht geschlossen werden.
' Dies macht Windows automatisch
pt(0).x = 10: pt(0).y = 10
pt(1).x = 10: pt(1).y = 50
pt(2).x = 50: pt(2).y = 80
pt(3).x = 100: pt(3).y = 500
pt(4).x = 500: pt(4).y = 550
pt(5).x = 500: pt(5).y = 80
pt(6).x = 100: pt(6).y = 500
pt(7).x = 500: pt(7).y = 550

rgn = CreatePolygonRgn(pt(0), 8, 1)


Nachdem eine Region erstellt wurde, muss man dem Fenster noch sagen, dass er diese als sogenannte "Clipping"-Region verwenden soll.
Danach müssen alle erstellten Objekte aus dem speicher gelöscht werden.

' Region an ein Fenster verweisen. (dabei ist es egal welche
' Fensterklasse. d.H. auch Textboxen, Comboboxen...)
SetWindowRgn Me.hwnd, rgn, True
' Speicherbereich der Region freigegeben...und fertig
DeleteObject rgn


Um mehrere Regionen zu Kombinieren, muß man erstmal mehrere anlegen. Danach kann man immer 2 zu einer machen.(wobei eine von beiden überschrieben wird)

' 2 Regionen vereint....
Dim rgn1 As Long, rgn2 As Long
rgn1 = CreateRectRgn(0, 0, 200, 200)
rgn2 = CreateRectRgn(300, 300, 400, 400)

CombineRgn rgn1, rgn1, rgn2, RGN_XOR
SetWindowRgn Me.hwnd, rgn1, True
DeleteObject rgn1
DeleteObject rgn2